FINISH
/clear
  
/FILNAME,disco,ON


Ri = 0.2   !m raggio interno 
R0 = 0.28  !m raggi di calettamento
Re = 0.44  !m raggio esterno
H =  0.05  !m spessore
n =  3000  !giri/min
iR = 0.002 !m/m interferenza relativa
ndiv = 5   !numero di divisioni sul semi-spessore


/PREP7  !ingresso ambiente di preprocessing

ET,1,PLANE42

KEYOPT,1,3,1  !axisymmetric

MP,EX,  1,200e9  
MP,PRXY,1,0.3  
MP,DENS,1,7800 

!creazione keypoint
K, 101, Ri, 0
K, 102, R0, 0
K, 103, R0, H/2
K, 104, Ri, H/2

K, 201, R0, 0
K, 202, Re, 0
K, 203, Re, H/2
K, 204, R0, H/2

!creazione linee
LSTR, 101, 102  !L1
LSTR, 102, 103  !L2
LSTR, 103, 104  !L3
LSTR, 104, 101  !L4

LSTR, 201, 202  !L5
LSTR, 202, 203  !L6
LSTR, 203, 204  !L7
LSTR, 204, 201  !L8

!creazione aree
AL, 1,2,3,4  
AL, 5,6,7,8  

!divisione linee
LESIZE,2,,,ndiv,  
LESIZE,4,,,ndiv,
LESIZE,1,,,50,-5, 
LESIZE,3,,,50,-5, 

LESIZE,6,,,ndiv,  
LESIZE,8,,,ndiv,
LESIZE,5,,,100,-5, 
LESIZE,7,,,100,-5, 

!crazione mesh
MSHKEY,1

AMESH,all

!vincolo di simmetria
DL,1, ,UY,   
DL,5, ,UY,   

*do, i,0,ndiv      !ciclo sui nodi di interfaccia

    asel,S,AREA,,1 !selezione area disco interno
    nsla,S,1       !selezione nodi appartenenti all'area selezionata
    nodo_int=NODE(R0,i*H/2/ndiv,0)
    
    asel,S,AREA,,2 !selezione area disco esterno
    nsla,S,1       !selezione nodi appartenenti all'area selezionata
    nodo_est=NODE(R0,i*H/2/ndiv,0)
    
    CE,i+1,iR*R0,nodo_est,UX,1,nodo_int,UX,-1,  !equazione di vincolo

*enddo
    
allsel

!velocità angolare attorno all'asse Y
OMEGA,0,n*2*3.141592/60,0

FINISH  


/SOL    !ingresso ambiente di soluzione

!calcolo soluzione
SOLVE   

FINISH  


/POST1  !ingresso ambiente di postelaborazione

!definizione path radiale
PATH,raggio,2,7,100,     !100 righe x 7 colonne
PPATH, 1, ,Ri,0,0        !punto iniziale
PPATH, 2, ,Re,0,0        !punto finale

PDEF,Sigma_R, S,  X,AVG  !map onto path
PDEF,Sigma_C, S,  Z,AVG  
PDEF,Sigma_Eq,S,EQV,AVG

!creazione del grafico
PLPATH,Sigma_R,Sigma_C,Sigma_Eq  


!estrazione dei risultati per il disco INTERNO
asel,S,AREA,,1 !selezione nodi disco interno
nsla,S,1       

n=NODE(Ri,0,0) !raggio interno
*GET,sigR_int,NODE,n,S,X
*GET,sigC_int,NODE,n,S,Z

n=NODE(R0,0,0) !raggio di calettamento (disco interno)
*GET,sigR_cal,NODE,n,S,X
*GET,sigC_cal,NODE,n,S,Z


!estrazione dei risultati per il disco ESTERNO
asel,S,AREA,,2 !selezione nodi disco esterno
nsla,S,1    

n=NODE(R0,0,0) !raggio di calettamento (disco esterno)
*GET,sigR_cal,NODE,n,S,X
*GET,sigC_cal,NODE,n,S,Z

n=NODE(Re,0,0) !raggio esterno
*GET,sigR_est,NODE,n,S,X
*GET,sigC_est,NODE,n,S,Z


!salvataggio dati path su file Excel
PAGET,data,TABLE
PAGET,dataLab,Label
*MWRITE, data, PathData, csv,
%G; %G; %G; %G; %G; %G; %G; %G; %G; %G;
*MWRITE, dataLab, PDataLab, csv,
(A,2X)


/eof

!salvataggio immagini
/RGB,INDEX,100,100,100, 0   !inversione colori background/foreground
/RGB,INDEX, 0, 0, 0,15  

/SHOW,PNG,,0   !salvataggio grafico formato .png
/GFILE,1200, 
PLPATH,Sigma_R,Sigma_C,Sigma_Eq  
/SHOW,CLOSE 

/SHOW,JPEG,,0     !salvataggio plot formato .jpg
JPEG,QUAL,100,  
/GFILE,1200, 
/DSCALE,1,1.0
PLNSOL,S,EQV
/SHOW,CLOSE 

/RGB,INDEX,100,100,100, 15   !ripristino colori
/RGB,INDEX, 0, 0, 0,0  
/REPLOT 


!FINISH  
/eof