FINISH
/clear
  
/FILNAME,disco,ON


Re =      1000   !mm raggio esterno
He =        13   !mm spessore esterno
omega = 314.15   !rad/s
ro =    7.8e-9   !ton/mm^3 densità 
Young = 200000   !MPa
sigma0 =   300   !MPa tensione ammissibile

div = 100     !numero delle divisioni sul raggio


/PREP7  !ingresso ambiente di preprocessing

ET,1,PLANE42

KEYOPT,1,3,1  !axisymmetric

MP,EX,  1, Young   
MP,PRXY,1, 0.3  
MP,DENS,1, ro      


!creazione keypoint

*do,i,0,div
	
   r = i*Re/div
   h = he*EXP(ro*omega**2/2/sigma0*(Re**2-r**2))
   K, i+1, r, h/2
   
*enddo

K, div+2,  0, 0
K, div+3, Re, 0

!creazione linee
LSTR,     1,  div+2  !L1
LSTR, div+2,  div+3  !L2
LSTR, div+3,  div+1  !L3

*do, i, 1, div  
    LSTR, i, i+1
*enddo

!creazione aree
AL, all  

!crazione mesh
ESIZE, Re/div/4,   !global size
MSHKEY,0           !free mesh
AMESH,all   

!vincolo di simmetria
DL,1, ,UX,   
DL,2, ,UY,   

!velocità angolare attorno all'asse Y
OMEGA,0,omega,0

!sigma radiale raggio esterno
SFL,3,PRES,-Sigma0, 
 
FINISH  



/SOL    !ingresso ambiente di soluzione

SOLVE   !calcolo soluzione

FINISH  



/POST1  !ingresso ambiente di postelaborazione

!definizione path radiale
PATH,raggio,2,7,100,     !100 righe x 7 colonne
PPATH, 1, , 0,0,0        !punto iniziale
PPATH, 2, ,Re,0,0        !punto finale

PDEF,Sigma_R, S,  X,AVG  !map onto path
PDEF,Sigma_C, S,  Z,AVG  
PDEF,Sigma_Eq,S,EQV,AVG

!creazione del grafico
PLPATH,Sigma_R,Sigma_C,Sigma_Eq