FINISH
/CLEAR

!parametri di progetto e grandezze derivate
H=0.05
B=0.0045
BT=0.002
rr=B-BT


!Analisi termica

/PREP7  

!Elementi termici: piano a 4 nodi e brick a 8 nodi  
ET,1,PLANE55
ET,2,SOLID70

! Definizione materiale 1: alluminio
MP,EX,1,70e9    
MP,PRXY,1,.33 
TB,BISO,1,1,2,  
TBDATA,,70e6,1500e6,,,,
UIMP,1,REFT,,,25
MP,ALPX,1,24.2e-6   
MP,KXX,1,180

! Definizione materiale 2: rame
MP,EX,2,110e9  
MP,PRXY,2,0.35 
TB,BISO,2,1,2,  
TBDATA,,90e6,2200e6
UIMP,2,REFT,,,25
MP,ALPX,2,12.5e-6    
MP,KXX,2,360

! Definizione geometria
BLC4,0,0,B,0.004   
BLC4,0,0.004,B,H-0.004   
BLC4,BT,0.008+rr,rr,H-rr-0.008 
CYL4,B,0.008+rr,rr 
ASBA,       2,       3  
ASBA,       5,       4  
AGLUE,ALL  

! Definizione attributi materiali
ASEL, , , ,       3 
AATT,       1, ,   1,       0,  
ASEL,ALL
ASEL, , , ,       1 
AATT,       2, ,   1,       0,  
ASEL,ALL

! Dimensioni mesh piana di appoggio
AESIZE,ALL,2/3/1000,
MSHKEY,0
AMESH,ALL  

! Opzioni di estrusione
TYPE,   1   
EXTOPT,ESIZE,40,1,  
EXTOPT,ACLEAR,0 
EXTOPT,ATTR,1,0,0   

! Creazione mesh di volume per estrusione
VEXT,ALL, , ,0,0,0.05

! Eliminazione geometria di appoggio (i comandi ADELE nella mia analisi non son serviti, ma potrebbero servire)
ACLEAR,ALL
!ADELE,1, , ,1
!ADELE,13, , ,1

! Applicazione carico termico: flusso entrante
SFA,4,1,HFLUX,60/0.05/0.05*2 

! Applicazione condizioni al contorno termiche: scambio per convezione forzata
SFA,10, ,CONV,45,40 
SFA,11, ,CONV,45,40   
SFA,11, ,CONV,45,40   

! eventuale applicazione condizioni al contorno termiche sulle pareti laterali
!SFA,8, ,CONV,45,40 
!SFA,2, ,CONV,45,40   
!SFA,3, ,CONV,45,40 
!SFA,1, ,CONV,45,40 
   
FINISH
/SOL

! Soluzione termica
SOLVE

FINISH  
/POST1  
 
! Visualizzazione campo di temperatura
PLNSOL, TEMP,, 0



! Analisi meccanica

FINISH  
/PREP7 

! Passaggio da elementi termici a elementi strutturali 
ETCHG,TTS   
!*  

! lettura campo di temperatura da analisi termica (Qui al posto di file potreste avere un jobname diverso)
LDREAD,TEMP,,, , ,'file','rth',' '  

! applicazione vincoli esterni e di simmetria
DA,4,UY,0
DA,7,UX,0
DA,13,UX,0
DA,7,UZ,0
DA,13,UZ,0

! Selezione nodi appartenenti alla superficie di collegamento con aletta successiva e coupling dei nodi in 
! direzione X 
ASEL,S, , ,5
ASEL,A, , ,9
NSLA,S,1
CP,1,UX,ALL
ALLSEL,ALL

FINISH  
/SOL

! Opzioni di soluzione non lineare: auto time stepping
NSUBST,50,0,0   
AUTOTS,1
TIME,1  

SOLVE

FINISH  
/POST1

! Visualizzazione campo di tensione di von Mises
PLNSOL, S,EQV, 0,1.0