FINISH
/clear


!inserimento dei parametri geometrici 
!attraverso finestra di dialogo

*ask, hhratio, H/h (>1)
*ask, rhratio, r/h (>0)
!selezione tensione piana / deformazione piana
*ask, keyopt, Element behavior (Plane stress ->0, Plane strain ->2)


!apertura dell'ambiente di preprocessor
/PREP7    

!scelta del tipo di elemento
ET,1,PLANE42 
KEYOPT,1,3,keyopt  !opzione tensione piana / deformazione piana
		
!definizione delle proprietą  del materiale
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,EX,1,,200e3  !MPa  
MPDATA,PRXY,1,,0.3
		
h2=10         !altezza minore (analisi adimensionale, va bene un valore qualsiasi)
h1=hhratio*h2 !altezza maggiore
r=rhratio*h2  !raggio d'intaglio
L=h1+2*r      !lunghezza totale
xc=L/2        !x centro raccordo
yc=h2/2+r     !y centro raccordo

		
!creazione aree 
BLC4,0,0,L,h1/2  
CYL4,xc,yc,r
BLC4,xc,h2/2,L/2,(h1-h2)/2  
*if, h1/2, NE, yc, then  !evita la creazione di un rettangolo con altezza nulla
   BLC4,xc,yc,-r,h1/2-yc  
*endif
	
!sottrazione di aree
ASBA,1,all

SMRT,3  !Smart size
AMESH,all   

!primo refinement 
NSEL,S,LOC,X, xc-r, xc+0.5*r  
NSEL,R,LOC,Y, yc-1.5*r, yc
nref,all
!secondo refinement
NSEL,S,LOC,X, xc-0.5*r, xc+0.25*r  
NSEL,R,LOC,Y, yc-1.25*r, yc-.5*r
nref,all

allsel,all
!/eof

		
!applicazione vincoli e carichi
LSEL,S,LOC,X,0  
LSEL,A,LOC,Y,0  
DL,all,,UX,0	

KSEL,S,LOC,X,0
KSEL,R,LOC,Y,0
DK,all,UY,0

allsel,all

!sforzo di trazione attraverso il parametro 'sigmaNom'
sigmaNom=100 !MPa
LSEL,S,LOC,X,L  
SFL,all,PRES,0,-sigmaNom  !zero sull'asse di simmetria, sigmaNom sulla fibra superiore 

allsel,all

FINISH

		
!entra nel solutore
/SOLU
	
!avvia la soluzione
SOLVE   	

FINISH		


!entra nell'ambiente di post-processing
/POST1  

!visualizzazione della soluzione nodale "sigma x"
PLNSOL, S,X, 0,1.0

!estrazione del valore massimo della sigma x e 
!e assegnazione al parametro max_sx
NSORT,S,X 
*GET,max_sx,SORT, ,MAX		

!calcola il valore del coefficiente di intaglio
Kt=max_sx/sigmaNom

*MSG, UI, Kt
Kt = %5.2F


FINISH