FINISH
/clear

!!!!  *** AUXILIARY HOLES ***


!lavoro in unità "ingegneristiche" : N, mm, e quindi MPa

!inserimento dei parametri geometrici 'radius' e 'gap'
!attraverso finestra di dialogo

*ask, radius, AUXILIARY HOLE RADIUS (10-20 mm)
*ask, gap, GAP LENGTH BETWEEN HOLE EDGES (~2 mm)


!apertura dell'ambiente di preprocessor
/PREP7    

!scelta del tipo di elemento
ET,1,PLANE42 
		
!definizione delle proprietà del materiale
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,EX,1,,200e3  !MPa  
MPDATA,PRXY,1,,0.3
		
!creazione area rettangolare da due angoli
BLC4,0,0,500,200  !mm
		
!creazione delle due aree circolari dati centro e raggio
CYL4,0,0,20 
CYL4,20+gap+radius,0,radius
	
!sottrazione di aree
!sottrazione dell'area 2 (cerchio centrato nell'origine) dall'area 1 (rettangolo)
ASBA,	1,2

!sottrazione l'area 3 (cerchio ausiliario) dall'area 4 (risultato dell'operazione precedente)
ASBA,	4,3


!operazioni per la creazione della mesh

!seleziona le linee che costituiscono i 3 archi:
LSEL,S,,,5
LSEL,A,,,9
LSEL,A,,,10
				
!sizing delle linee selezionate:
LESIZE,ALL,,,30,,,,,1
			
!riselezione di tutte le entità
ALLSEL,ALL
				
!suddivisione linea di separazione dei due fori:
LESIZE,4,radius/10,,,,,,,1
		
!suddivisione linee adiacenti al vertice nell'origine 
LSEL,S,,,1
LSEL,A,,,14

LESIZE,ALL,,,50,0.1,,,,1

ALLSEL,ALL	
		
!suddivisione linee adiacenti al vertice opposto all'origine
LESIZE,3,,,50,,,,,,,1
LESIZE,2,,,20,,,,,,,1	
		
!creazione della mesh 
AMESH,ALL	

!visualizzazione elementi a scacchiera colorata
/NUMBER,1   
/PNUM,ELEM,1
EPLOT

!/eof
		
!applicazione vincoli e carichi
!vincoli di simmetria
DL,14, ,UX,0	
DL, 1, ,UY,0
DL, 4, ,UY,0
		
!sforzo di trazione attraverso il parametro 'sigmaNom'
sigmaNom=100 !MPa
SFL,2,PRES,-sigmaNom

FINISH


		
!entra nel solutore
/SOLU
	
!avvia la soluzione
SOLVE   	

FINISH		




!entra nell'ambiente di post-processing
/POST1  

!visualizzazione della soluzione nodale "sigma x"
PLNSOL, S,X, 0,1.0

!estrazione del valore massimo della sigma x e 
!e assegnazione al parametro max_sx
NSORT,S,X 
*GET,max_sx,SORT, ,MAX		

!calcola il valore del coefficiente di intaglio
Kt=max_sX/sigmaNom

*MSG, UI, Kt
Kt = %5.2F


FINISH