FINISH
/clear

!!!!  *** SPRING BACK ***

!definizione parametri

radius    = 20   !mm


!ambiente di preprocessamento
/PREP7    

!scelta del tipo di elemento
ET,1,PLANE42 
		
!definisce le proprietà del materiale
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,EX,1,,200e3  !MPa
MPDATA,PRXY,1,,0.3
!modello di materiale bilineare con incrudimento
TB,BISO,1,1,2,  
TBTEMP,0
TBDATA,,400,1000,,,, !MPa


!creazione area rettangolare da due angoli
BLC4,0,0,500,200
		
!creazione di una area circolare dati centro e raggio
CYL4,0,0,radius 
	
!sottrazione dell'area 2 (cerchio centrato nell'origine) dall'area 1 (rettangolo)
ASBA, 1,2

!operazioni per la creazione della mesh

!sizing bordo foro
LESIZE,5,,,30,,,,,1
			
!suddivisione linee adiacenti al vertice nell'origine 
LESIZE,10,,,50,0.1,,,,1
LESIZE, 9,,,50,0.1,,,,1
		
!suddivisione linee adiacenti al vertice opposto all'origine
LESIZE,3,,,20,,,,,,,1
LESIZE,2,,,10,,,,,,,1	
		
!creazione della mesh 
AMESH,ALL	
		
/NUMBER,1   
/PNUM,ELEM,1
EPLOT
		
!applicazione vincoli di simmetria
DL,10,,UX,0	
DL, 9,,UY,0

!/eof  

FINISH
		


!entra nel solutore
/SOLU

!applicazioni carico di trazione in campo plastico
SFL,2,PRES,-200 !MPa

SOLVE   !primo LOAD STEP	

!cancellazione carico di trazione
SFLDELE,all,PRES    

SOLVE   !secondo LOAD STEP  (scarico) 

FINISH		

	

! entra nell'ambiente di post-processing
/POST1  

!visualizzazione della soluzione nodale "epsilon plastica equivalente"
PLNSOL, EPPL,EQV, 0,1.0 
/DSCALE,1,1.0   
/REPLOT