FINISH
/clear
/FILNAME,Trans_Full,0  


/PREP7  

!scelta del tipo di elemento
ET,1,SHELL63
!definizione dello spessore
R,1,0.003,   

!materiale: acciaio
MPTEMP,1,0  
MPDATA,EX,1,,200e9  !Pa
MPDATA,PRXY,1,,0.3  
MPTEMP,1,0  
MPDATA,DENS,1,,7800 !kg/m^3

!definizione della geometria
!keypoint
K,1, 0,   0,   0 
K,2, 2, 0.1,   0 
K,3, 0, 0.3,   0 
K,4, 2, 0.3,   0 
K,5, 0,   0, 0.1
K,6, 2, 0.1, 0.1 
K,7, 0, 0.3, 0.1
K,8, 2, 0.3, 0.1
!aree
A, 1, 3, 4, 2  
A, 7, 8, 4, 3
A, 5, 1, 2, 6
!raccordi
AFILLT, 2, 1, 0.015   
AFILLT, 6, 3, 0.015   

!divisione delle linee
LSEL,S,LOC,X,0,2  
LSEL,U,LOC,X,0  
LSEL,U,LOC,X,2  
LESIZE,all, , ,20

LSEL,S,LOC,Z,0.015,0.1  
LESIZE,all, , ,2

LSEL,S,LOC,X,0 
LSEL,A,LOC,X,2 
LSEL,R,LOC,Z,0 
LESIZE,all, , ,5

LSEL,S,LOC,X,0 
LSEL,A,LOC,X,2 
LSEL,R,LOC,Z,0,0.015
LSEL,U,LOC,Z,0
LESIZE,all, , ,3

allsel,all
!/eof
/VIEW,1,1,2,3   
/AUTO,1 
/REP,FAST 

!costruzione mesh
AMESH,all   

!applicazione vincolo alla sezione di incastro
LSEL,S,LOC,X,0  
DL,all,,ALL,0	

allsel,all

FINISH  
!/eof



!Full-Transient Solution
/SOLU                
ANTYPE,TRANS         ! Transient analysis
TRNOPT,FULL          ! full

! primo Load Step
TIME,2               ! tempo di fine step
DELTIM,0.1           ! time step 
KBC,0                ! applicazione "ramped" del carico
OUTRES,BASIC,1       ! salvataggio risultati ogni substep
FK,20,FY,-10000      ! carico
LSWRITE,1            ! salvataggio del primo LS 

! Secondo Load Step
TIME,7               ! tempo di fine step
DELTIM,0.01          ! time step 
KBC,1                ! applicazione "stepped" del carico
OUTRES,BASIC,1       ! salvataggio risultati ogni singolo substep
FKDELE,ALL,ALL       ! rimozione carico		 		
LSWRITE,2            ! salvataggio secondo LS 

LSSOLVE,1,2	     !calcolo soluzione LS da 1 a 2

FINISH


/POST26 
/UI,COLL,1  
NUMVAR,200  

NSOL,2,86,U,Y,UY_2  !estrazione dello spostamento Y di un nodo
STORE,MERGE 

XVAR,1              !asse X
PLVAR,2             !plot grandezza 2

!salvataggio in forma testuale 
*DIM,_P26_EXPORT,TABLE,520,1   
VGET,_P26_EXPORT(1,0),1 
VGET,_P26_EXPORT(1,1),2 

/OUTPUT,'DATA_full','TXT','.'
*VWRITE,_P26_EXPORT(1,0),_P26_EXPORT(1,1)   
%12.5G	%10.3G 
/OUTPUT,TERM

FINISH