FINISH
/clear

!!!!  *** HOLE COLD EXPANSION ***

!definizione parametri

radius    = 20   !mm
expansion = 0.1  !mm


!ambiente di preprocessamento
/PREP7    

!scelta del tipo di elemento
ET,1,PLANE42 
		
!definisce le proprietà del materiale
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,EX,1,,200e3  !MPa
MPDATA,PRXY,1,,0.3
!modello di materiale bilineare con incrudimento
TB,BISO,1,1,2,  
TBTEMP,0
TBDATA,,400,1000,,,, !MPa


!creazione area rettangolare da due angoli
BLC4,0,0,500,200
		
!creazione di una area circolare dati centro e raggio
CYL4,0,0,radius 
	
!sottrazione dell'area 2 (cerchio centrato nell'origine) dall'area 1 (rettangolo)
ASBA, 1,2

!operazioni per la creazione della mesh

!sizing bordo foro
LESIZE,5,,,30,,,,,1
			
!suddivisione linee adiacenti al vertice nell'origine 
LESIZE,10,,,50,0.1,,,,1
LESIZE, 9,,,50,0.1,,,,1
		
!suddivisione linee adiacenti al vertice opposto all'origine
LESIZE,3,,,20,,,,,,,1
LESIZE,2,,,10,,,,,,,1	
		
!creazione della mesh 
AMESH,ALL	
		
/NUMBER,1   
/PNUM,ELEM,1
EPLOT
		
!applicazioni vincoli di simmetria
DL,10,,UX,0	
DL, 9,,UY,0

!applicazioni carico di espansione
LSEL,S,,,5 
NSLL,S,0     !solo nodi interni!! 

CSYS,1       !attivazione sistema di riferimento polare
NROTAT,all   !allineamento dei riferimenti nodali al riferimento attivo

D,all,,expansion,,,,UX,,,,,  !applicazione spostamento radiale
CSYS,0       !ritorno al riferimento cartesiano

!applicazione spostamento radiale ai nodi di estremità 
!nel riferimento cartesiano
KSEL,S,,,6 
NSLK,S  
D,all,,expansion,,,,UY,,,,,

KSEL,S,,,5 
NSLK,S  
D,all,,expansion,,,,UX,,,,,

ALLSEL,ALL  

/PSYMB,NDIR,1  !visualizzazione riferimenti nodali
NPLOT   

!/eof  

FINISH
		
!entra nel solutore
/SOLU

SOLVE   !primo LOAD STEP	

!cancellazione di tutti i vincoli
DDELE,all,ALL  

!applicazioni vincoli di simmetria
DL,10,,UX,0	
DL, 9,,UY,0

SOLVE   !secondo LOAD STEP  (scarico) 


!applicazioni carico di trazione
SFL,2,PRES,-100

SOLVE   !terzo LOAD STEP  (sollecitazione di lavoro a trazione) 

FINISH		
	

! entra nell'ambiente di post-processing
/POST1  

!visualizzazione della soluzione nodale "sigma x"
PLNSOL, S,X, 0,1.0
/DSCALE,1,1.0   
/REPLOT 

!estrazione del valore massimo della sigma x e lo salva nel parametro max_sx
NSORT,S,X 
*GET,max_sx,SORT, ,MAX		
		
!calcola il valore del coefficiente di intaglio
Kt=max_sX/100

*MSG, UI, Kt
Kt = %5.2F

FINISH