FINISH
/clear
/FILNAME,Tensile,0  

!inserimento dei parametri geometrici 


Rmin = 0.003  !(m) raggio sezione calibrata
Rmax = 0.0055 ! raggio codolo di afferraggio
Rrac = 0.015  ! raggio di raccordo

Lcal = 0.02   ! semilunghezza tratto calibrato
Ltot = 0.05   ! semilunghezza totole
Lrac = Rrac*sin(acos(1-(Rmax-Rmin)/Rrac)) !lunghezza tratto raccordato

!apertura dell'ambiente di preprocessor
/PREP7    

!scelta del tipo di elemento
ET,1,PLANE182 
KEYOPT,1,3,1  !opzione comportamento assialsimmetrico
		
!definizione delle proprietą  del materiale
MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,EX,1,,207e9  !MPa  
MPDATA,PRXY,1,,0.3

!modello di materiale elasto-plastico con incrudimento
!formula analitica di Voce
TB,NLIS,1,1,4,  
TBTEMP,0
TBDATA,,505e6,315e6,260e6,24,,  

		
!creazione aree 
BLC4,0,0,Rmin,Lcal
BLC4,0,Lcal,Rmax,Lrac 
BLC4,0,Lcal+Lrac,Rmax,Ltot-Lcal-Lrac 
CYL4,Rmin+Rrac,Lcal,Rrac
	
!sottrazione di aree
ASBA,2,4

!unione aree
NUMMRG,ALL

!divisione delle linee
LSEL,S,LOC,Y,0  
LSEL,A,LOC,Y,Lcal  
LSEL,A,LOC,Y,Lcal+Lrac
LESIZE,all, , ,15

LSEL,S,LOC,X,0  
LSEL,R,LOC,Y,0,Lcal  
LESIZE,all, , ,50,1/4

LSEL,S,LOC,X,Rmin  
LSEL,R,LOC,Y,0,Lcal  
LESIZE,all, , ,50,4

LSEL,S,LOC,X,0  
LSEL,R,LOC,Y,Lcal,Lcal+Rrac
LESIZE,all, , ,10

LSEL,S,LOC,X,Rmin,Rmax  
LSEL,R,LOC,Y,Lcal,Lcal+Rrac
LESIZE,all, , ,10

LSEL,S,LOC,X,0  
LSEL,R,LOC,Y,Lcal+Rrac,Ltot
LESIZE,all, , ,20,1/5

LSEL,S,LOC,X,Rmax  
LSEL,R,LOC,Y,Lcal+Rrac,Ltot
LESIZE,all, , ,20,5

LSEL,S,LOC,Y,Ltot  
LESIZE,all, , ,3

allsel,all

AMESH,all   

!/eof

		
!applicazione vincoli di simmetria
LSEL,S,LOC,X,0  
DL,all,,UX,0	

LSEL,S,LOC,Y,0  
DL,all,,UY,0	

!applicazione carico
LSEL,S,LOC,Y,Ltot  
DL,all,,UY,0.0075/2	

allsel,all

!/eof

FINISH

		
!entra nel solutore
/SOLU

NLGEOM,1
NSUBST,200,500,100  
OUTRES,ERASE
OUTRES,ALL,1

SOLVE  !avvia la soluzione
      	

FINISH		


!entra nell'ambiente di Time-History post-processing
/POST26 
NUMVAR,200  

NSOL,2,node(Rmin,0.0125,0),U,Y, UY_2 
STORE,MERGE 
  
RFORCE,3,node(0,Ltot,0),F,Y,FY_3   
STORE,MERGE 
  
RFORCE,4,node(Rmax*1/3,Ltot,0),F,Y, FY_4  
STORE,MERGE 
  
RFORCE,5,node(Rmax*2/3,Ltot,0),F,Y,FY_5   
STORE,MERGE 
  
RFORCE,6,node(Rmax*3/3,Ltot,0),F,Y,FY_6   
STORE,MERGE 

ADD,200,3,4 
ADD,199,200,5   
ADD,7,199,6,,Load   

XVAR,2   !asse X (Corsa)
PLVAR,7, !plot grafico Carico-Corsa


FINISH	

/eof
/POST1  

/EXPAND,18,AXIS,,,10,,2,RECT,HALF,,0.00001  
PLNSOL,EPPL,EQV 

/VIEW,1,1,1,1   
/ANG,1  
/ZOOM,1,SCRN,0.305252,0.217795,0.867073,0.403493
ANCNTR,50,0.5   !animazione